From 71eefcd38e76a7e57e1430c45324816de6bde9f0 Mon Sep 17 00:00:00 2001
From: Ton Voon <tonvoon@users.sourceforge.net>
Date: Thu, 23 Dec 2004 09:30:55 +0000
Subject: Another attempt at fixing check_http compile on Redhat EL3. Fixed
 check_icmp compile (Lynne Lawrence - 1087171) - still some code changes to
 check_icmp outstanding. Fixed compile of check_dhcp (complaining about
 socklen_t). Added acknowledgements for Coreutils and curl

git-svn-id: https://nagiosplug.svn.sourceforge.net/svnroot/nagiosplug/nagiosplug/trunk@1054 f882894a-f735-0410-b71e-b25c423dba1c
---
 m4/np_curl.m4 | 60 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 m4/np_curl.m4

(limited to 'm4')

diff --git a/m4/np_curl.m4 b/m4/np_curl.m4
new file mode 100644
index 00000000..64c3db54
--- /dev/null
+++ b/m4/np_curl.m4
@@ -0,0 +1,60 @@
+dnl These are for the libs and macros from curl
+dnl Currently utilising v7.12.3
+
+dnl We use jm_ for non Autoconf macros.
+dnl m4_pattern_forbid([^np_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
+dnl m4_pattern_forbid([^jm_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
+dnl m4_pattern_forbid([^gl_[ABCDEFGHIJKLMNOPQRSTUVXYZ]])dnl
+
+dnl These are all m4 things that need to be called
+dnl Usually in coreutils' prereq.m4, but this is a subset that we need
+AC_DEFUN([np_CURL],
+[
+  AC_REQUIRE([TYPE_SOCKLEN_T])
+])
+
+dnl Check for socklen_t: historically on BSD it is an int, and in
+dnl POSIX 1g it is a type of its own, but some platforms use different
+dnl types for the argument to getsockopt, getpeername, etc.  So we
+dnl have to test to find something that will work.
+AC_DEFUN([TYPE_SOCKLEN_T],
+[
+   AC_CHECK_TYPE([socklen_t], ,[
+      AC_MSG_CHECKING([for socklen_t equivalent])
+      AC_CACHE_VAL([curl_cv_socklen_t_equiv],
+      [
+         # Systems have either "struct sockaddr *" or
+         # "void *" as the second argument to getpeername
+         curl_cv_socklen_t_equiv=
+         for arg2 in "struct sockaddr" void; do
+            for t in int size_t unsigned long "unsigned long"; do
+               AC_TRY_COMPILE([
+                  #ifdef HAVE_SYS_TYPES_H
+                  #include <sys/types.h>
+                  #endif
+                  #ifdef HAVE_SYS_SOCKET_H
+                  #include <sys/socket.h>
+                  #endif
+
+                  int getpeername (int, $arg2 *, $t *);
+               ],[
+                  $t len;
+                  getpeername(0,0,&len);
+               ],[
+                  curl_cv_socklen_t_equiv="$t"
+                  break
+               ])
+            done
+         done
+
+         if test "x$curl_cv_socklen_t_equiv" = x; then
+            AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+         fi
+      ])
+      AC_MSG_RESULT($curl_cv_socklen_t_equiv)
+      AC_DEFINE_UNQUOTED(socklen_t, $curl_cv_socklen_t_equiv,
+                        [type to use in place of socklen_t if not defined])],
+      [#include <sys/types.h>
+#include <sys/socket.h>])
+])
+
-- 
cgit v1.2.3