Fixed compile on Tru64 5.1b (Ciro Iriarte - 1515435)

git-svn-id: https://nagiosplug.svn.sourceforge.net/svnroot/nagiosplug/nagiosplug/trunk@1438 f882894a-f735-0410-b71e-b25c423dba1c

2 files changed, 56 insertions, 0 deletions

diff --git a/m4/c-strtod.m4 b/m4/c-strtod.m4
new file mode 100644
index 00000000..ffeb4588
--- /dev/null
+++ b/m4/c-strtod.m4
@@ -0,0 +1,55 @@
+# c-strtod.m4 serial 6
+
+# Copyright (C) 2004, 2005 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# Written by Paul Eggert.
+
+AC_DEFUN([gl_C99_STRTOLD],
+[
+  AC_CACHE_CHECK([whether strtold conforms to C99],
+    [gl_cv_func_c99_strtold],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[/* On HP-UX before 11.23, strtold returns a struct instead of
+		long double.  Reject implementations like that, by requiring
+		compatibility with the C99 prototype.  */
+	     #include <stdlib.h>
+	     static long double (*p) (char const *, char **) = strtold;
+	     static long double
+	     test (char const *nptr, char **endptr)
+	     {
+	       long double r;
+	       r = strtold (nptr, endptr);
+	       return r;
+	     }]],
+           [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
+       [gl_cv_func_c99_strtold=yes],
+       [gl_cv_func_c99_strtold=no])])
+  if test $gl_cv_func_c99_strtold = yes; then
+    AC_DEFINE([HAVE_C99_STRTOLD], 1, [Define to 1 if strtold conforms to C99.])
+  fi
+])
+
+AC_DEFUN([gl_C_STRTOD],
+[
+  AC_LIBSOURCES([c-strtod.c, c-strtod.h])
+  AC_LIBOBJ([c-strtod])
+
+  dnl Prerequisites of lib/c-strtod.c.
+  AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
+  :
+])
+
+AC_DEFUN([gl_C_STRTOLD],
+[
+  AC_LIBSOURCES([c-strtold.c, c-strtod.h])
+  AC_LIBOBJ([c-strtold])
+
+  dnl Prerequisites of lib/c-strtold.c.
+  AC_REQUIRE([gl_C_STRTOD])
+  AC_REQUIRE([gl_C99_STRTOLD])
+  :
+])
diff --git a/m4/np_coreutils.m4 b/m4/np_coreutils.m4
index 44aa3b80..18c5f66b 100644
--- a/m4/np_coreutils.m4
+++ b/m4/np_coreutils.m4
@@ -11,6 +11,7 @@ dnl Usually in coreutils' prereq.m4, but this is a subset that we need
 AC_DEFUN([np_COREUTILS],
 [
   AC_REQUIRE([AM_STDBOOL_H])
+  AC_REQUIRE([gl_C_STRTOLD])
   AC_REQUIRE([gl_GETOPT])
   AC_REQUIRE([gl_AFS])
   AC_REQUIRE([gl_EXITFAIL])